home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib05.dsk / APPLE RAT.bas < prev    next >
BASIC Source File  |  2023-02-26  |  1KB  |  35 lines
  1. 10  REM  *********************************
  2. 20  REM  **   READ  APPLE  TEXT  FILES  **
  3. 30  REM  **   RAT  BY  TOM  GABRIELE    **
  4. 40  REM  *********************************
  5. 50  REM  INITIALIZE CONTROL
  6. 60  ONERR  GOTO 290
  7. 70 D$ =  CHR$(4)
  8. 80 R$ =  CHR$(13): REM  CARRIAGE RETURN
  9. 90 CA$ =  CHR$(1): REM  CONTROL-A
  10. 100  INPUT "DISK FILE NAME?";NF$: REM  GET THE FILENAME TO BE READ.
  11. 110  IF NF$ = ""  THEN  END 
  12. 115  PRINT D$;"VERIFY ";NF$: REM  CHECK FOR EXISTENCE OF FILE
  13. 120  PRINT D$;"OPEN ";NF$: REM  ACCESS NAMED FILE
  14. 130  PRINT D$;"READ ";NF$: REM  PREPARE FILE FOR READING
  15. 140 L$ = "": REM  INITIALIZE LINE TO NULL STRING
  16. 150  GET C$: REM  GET ONE CHARACTER FROM FILE.
  17. 160  IF C$ = R$  THEN 220: REM  IF CARRIAGE RETURN, END LINE
  18. 170  REM  CONVERT LOWER TO UPPER CASE
  19. 180 VC =  ASC(C$)
  20. 190  IF VC >96  AND VC <123  THEN C$ =  CHR$(VC -32)
  21. 200 L$ = L$ +C$: REM  APPEND NEW CHARACTER TO LINE
  22. 210  GOTO 150: REM  GET THE NEXT CHARACTER.
  23. 220  PRINT R$;D$: REM  SEE PAGE 54 OF DOS MANUAL.
  24. 230  PRINT CA$;L$: REM  OUTPUT LINE TO CRT
  25. 240  GOTO 130: REM  GET THE NEXT LINE
  26. 250  REM  NORMAL PROGRAM FINISH
  27. 260  PRINT "NORMAL EOF DETECTED."
  28. 270 F =  FRE(0): GOTO 100
  29. 280  REM  ERROR HANDLING
  30. 290 BOO =  PEEK(222)
  31. 300  PRINT D$;"CLOSE ";NF$
  32. 310  IF BOO = 5  THEN  GOTO 260
  33. 320  PRINT "ERROR NUMBER ";BOO;" OCCURRED."
  34. 330  END 
  35. 340  REM  (C) 1981 BY TOM GABRIELE